Think I finally got it.
I plan to post a recipe once I get remaining QB virtualization issues addressed, but in case a lurker just needs the ability to terminate QB processes from a script after the QB GUI is closed, this is working very well.
The script must run outside the bubble. For ThinApp use, put it on a share and call it from your ThinApp script as follows:
ExecuteExternalProcess "WSCRIPT.EXE " & Chr(34) & "\\Server\Share\Folder\ManageQBProcesses.vbs" & Chr(34)
Last but not least, The Script:
'******************************************************************************
'ManageQBProcesses.vbs
'******************************************************************************
'When QuickBooks closes, it leaves several processes running, one of which is
'large, to improve startup performance. But RAM consumption is too high for
'RDSH's for an idle program.
'
'This script watches for QB GUI exit, waits a configurable amount of time (to
'allow quick relaunches) and then terminates the "leftover" processes.
'
'There's no way (that I could find) to detect this scenario:
'1. QB opened without ever opening a QBW
'2. QB closed
'In this case, script and the "leftover" QB services will remain running until
'a normal QB session is launched and terminated, or until logoff. Unusual case,
'though, since QB opens previously opened file, if there was one.
'
'Designed and tested for QuickBooks 2012 Premier with QB startup tasks disabled.
'In other scenarios, different Processes may need to be monitored and
'termiminated. This can be changed in Configuration section.
'******************************************************************************
Dim objWMIService
strComputer = "."
'** CONFIGURATION **
'list of known QB processes left running after QB GUI exits
'these need to be the FILENAMES from the "Command Line" field in Task Manager
'which is not displayed by default
'often this is the same as the Image Name, but app virtualization may use a
'different Image Name than the executable name
strQBExecutables = Array("QBCFMonitorService.exe", "QBIDPService.exe", "QBW32.exe", "QBMsgMgr.exe", "QBUpdate.exe")
'timeout after closing QB before QB processes are terminated, in milliseconds
'-1 = no timeout; close immediately
intExitTimeout = 600000
'******************************************************************************
Set objWMIService = GetObject("winmgmts:" _
& "{impersonationLevel=impersonate}!\\" & strComputer & "\root\cimv2")
Do
'check to see when QB DB processes, QBDBMGR (remote QBW) and AX~3H6T9 (local QBW), are launched
'if EITHER is running, a QBW has been loaded, and we need to grab the PIDs
Set colMonitoredProcesses = objWMIService. _
ExecNotificationQuery("select * from __instancecreationevent " _
& " within 1 where TargetInstance isa 'Win32_Process'")
intDbPID = 0
intAxPID = 0
Do
Set objLatestProcess = colMonitoredProcesses.NextEvent
strCL = objLatestProcess.TargetInstance.CommandLine
If Len(strCL) > 0 Then
Select Case ParseFilename(strCL)
Case "QBDBMGR.EXE" 'remote data file
intDbPID = objLatestProcess.TargetInstance.ProcessID
Case "AX~3H6T9.EXE" 'local data file
intAxPID = objLatestProcess.TargetInstance.ProcessID
Case Else
End Select
End If
Loop Until intDbPID > 0 And intAxPID > 0
'now that we have the PIDs, monitor both to see when they terminate
'by the time we get here, one or the other has already closed
'the other will terminate when QB closes, so that's what we want to watch for
Set colMonitoredProcesses = objWMIService. _
ExecNotificationQuery("select * from __instancedeletionevent " _
& "within 1 where TargetInstance isa 'Win32_Process'")
intLatestPID = 0
Do
Set objLatestProcess = colMonitoredProcesses.NextEvent
intLatestPID = objLatestProcess.TargetInstance.ProcessID
Loop Until intLatestPID = intDbPID Or intLatestPID = intAxPID
Set colMonitoredProcesses = Nothing
'when both are terminated, QB has been closed, processes now on death row
If intExitTimeout > 0 Then
'wait a bit in case we get a pardon from the governer (i.e. open QB again)
WScript.Sleep intExitTimeout
End If
'after timeout, check to see if either DB process is running; only thing that will save us
Set colProcess = objWMIService.ExecQuery("SELECT * FROM Win32_Process")
For Each objProcess in colProcess
strCL = UCase(objProcess.CommandLine)
If Len(strCL) > 0 Then
strCL = ParseFilename(strCL)
blnResume = (strCL = "QBDBMGR.EXE" Or strCL = "AX~3H6T9.EXE")
If blnResume Then
Exit For
End If
End If
Next 'colProcess
Loop While blnResume
'nope, this is Texas; all appeals denied, guv couldn't care less; kill QB services
For each objProcess in colProcess
strCL = objProcess.CommandLine
For intCntr = 0 To UBound(strQBExecutables)
If Instr(1, UCase(strCL), UCase(strQBExecutables(intCntr))) > 0 Then
objProcess.Terminate
End If
Next 'intCntr
Next 'objProcess
'******************************************************************************
Function ParseFilename(strCL)
'parse executable name from command line
'this will allow it to work whether Image Name is the executable
'or if it's the name assigned by a virtualizer
strPF = strCL
strPF = UCase(strCL)
'if 1st character is quoted, truncate at close quote
If Left(strPF, 1) = Chr(34) Then
intPos = InStr(2, strPF, Chr(34))
strPF = Mid(strPF, 2, intPos - 2)
Else 'truncate at first space
intPos = InStr(1, strPF, " ")
If intPos > 0 Then
strPF = Left(strPF, intPos - 1)
End If
End If
'if fully qualified, strip the path
intPos = InStrRev(strPF, "\")
If intPos > 0 Then
strPF = Mid(strPF, intPos + 1)
End If
ParseFilename = strPF
End Function
'******************************************************************************